#version 460
layout(local_size_x = 4, local_size_y = 4, local_size_z = 4) in;

const int CHUNK_SIZE = 16;
const int CHUNK_AREA = CHUNK_SIZE * CHUNK_SIZE;

// A 1D storage buffer representing a flat 3D array of voxel IDs
layout(std430, binding = 0) buffer VoxelData {
    uint voxels[];
};

layout(push_constant) uniform ChunkOffset {
    ivec3 chunkPos;
    int padding0;
};
// Description : Array and textureless GLSL 2D/3D/4D simplex
//               noise functions.
//      Author : Ian McEwan, Ashima Arts.
//  Maintainer : stegu
//     Lastmod : 20110822 (ijm)
//     License : Copyright (C) 2011 Ashima Arts. All rights reserved.
//               Distributed under the MIT License. See LICENSE file.
//               https://github.com

vec4 permute(vec4 x) { return mod(((x * 34.0) + 1.0) * x, 289.0); }
vec4 taylorInvSqrt(vec4 r) { return 1.79284291400159 - 0.85373472095314 * r; }

float simplex_noise(vec3 v) {
    const vec2 C = vec2(1.0/6.0, 1.0/3.0);
    const vec4 D = vec4(0.0, 0.5, 1.0, 2.0);

    // First corner
    vec3 i  = floor(v + dot(v, C.yyy));
    vec3 x0 = v - i + dot(i, C.xxx);

    // Other corners
    vec3 g = step(x0.yzx, x0.xyz);
    vec3 l = 1.0 - g;
    vec3 i1 = min(g.xyz, l.zxy);
    vec3 i2 = max(g.xyz, l.zxy);

    //   x0 = x0 - 0.0 + 0.0 * C.xxx;
    //   x1 = x0 - i1  + 1.0 * C.xxx;
    //   x2 = x0 - i2  + 2.0 * C.xxx;
    //   x3 = x0 - 1.0 + 3.0 * C.xxx;
    vec3 x1 = x0 - i1 + C.xxx;
    vec3 x2 = x0 - i2 + C.yyy; // 2.0*C.x = 1/3 = C.y
    vec3 x3 = x0 - D.yyy;      // -1.0+3.0*C.x = -0.5 = -D.y

    // Permutations
    i = mod(i, 289.0);
    vec4 p = permute(permute(permute(
            i.z + vec4(0.0, i1.z, i2.z, 1.0))
    + i.y + vec4(0.0, i1.y, i2.y, 1.0))
    + i.x + vec4(0.0, i1.x, i2.x, 1.0));

    // Gradients: 7x7 points over a square, mapped onto an octahedron.
    // The ring size 17*17 = 289 is close to a multiple of 49 (49*6 = 294)
    float n_ = 0.142857142857; // 1.0/7.0
    vec3  ns = n_ * D.wyz - D.xzx;

    vec4 j = p - 49.0 * floor(p * ns.z);  //  mod(p,7*7)

    vec4 x_ = floor(j * ns.z);
    vec4 y_ = floor(j - 7.0 * x_);    // mod(j,N)

    vec4 x = x_ * ns.x + ns.yyyy;
    vec4 y = y_ * ns.x + ns.yyyy;
    vec4 h = 1.0 - abs(x) - abs(y);

    vec4 b0 = vec4(x.xy, y.xy);
    vec4 b1 = vec4(x.zw, y.zw);

    //vec4 s0 = vec4(lessThan(b0,0.0))*2.0 - 1.0;
    //vec4 s1 = vec4(lessThan(b1,0.0))*2.0 - 1.0;
    vec4 s0 = floor(b0) * 2.0 + 1.0;
    vec4 s1 = floor(b1) * 2.0 + 1.0;
    vec4 sh = -step(h, vec4(0.0));

    vec4 a0 = b0.xzyw + s0.xzyw * sh.xxyy;
    vec4 a1 = b1.xzyw + s1.xzyw * sh.zzww;

    vec3 p0 = vec3(a0.xy, h.x);
    vec3 p1 = vec3(a0.zw, h.y);
    vec3 p2 = vec3(a1.xy, h.z);
    vec3 p3 = vec3(a1.zw, h.w);

    // Normalise gradients
    vec4 norm = taylorInvSqrt(vec4(dot(p0,p0), dot(p1,p1), dot(p2, p2), dot(p3,p3)));
    p0 *= norm.x;
    p1 *= norm.y;
    p2 *= norm.z;
    p3 *= norm.w;

    // Mix final noise value
    vec4 m = max(0.6 - vec4(dot(x0,x0), dot(x1,x1), dot(x2,x2), dot(x3,x3)), 0.0);
    m = m * m;

    // Returns a value scaled exactly between -1.0 and 1.0
    return 42.0 * dot(m * m, vec4(dot(p0,x0), dot(p1,x1), dot(p2,x2), dot(p3,x3)));
}
float noise2D(vec2 p) {
    return simplex_noise(vec3(p.x, p.y, 0.0));
}

float fbm(vec2 p, int octaves, float lacunarity, float gain) {
    float value = 0.0;
    float amplitude = 0.5;
    float frequency = 1.0;
    float amplitudeSum = 0.0;

    for (int i = 0; i < octaves; i++) {
        value += noise2D(p * frequency) * amplitude;
        amplitudeSum += amplitude;

        frequency *= lacunarity;
        amplitude *= gain;
    }

    return value / amplitudeSum;
}

float ridgedFbm(vec2 p, int octaves, float lacunarity, float gain) {
    float value = 0.0;
    float amplitude = 0.5;
    float frequency = 1.0;
    float amplitudeSum = 0.0;

    for (int i = 0; i < octaves; i++) {
        float n = noise2D(p * frequency);
        n = 1.0 - abs(n);
        n = n * n;

        value += n * amplitude;
        amplitudeSum += amplitude;

        frequency *= lacunarity;
        amplitude *= gain;
    }

    return value / amplitudeSum;
}

vec2 domainWarp(vec2 p) {
    float wx = fbm(p + vec2(17.31, 91.73), 3, 2.0, 0.5);
    float wz = fbm(p + vec2(43.17, 12.89), 3, 2.0, 0.5);

    return p + vec2(wx, wz) * 35.0;
}

float terrainHeight(vec2 worldXZ) {
    vec2 p = worldXZ;

    vec2 warped = domainWarp(p * 0.006);

    float continent = fbm(warped * 0.45, 5, 2.0, 0.5);
    continent = continent * 0.5 + 0.5;

    float hills = fbm(p * 0.025, 5, 2.0, 0.48);
    float detail = fbm(p * 0.09, 3, 2.1, 0.45);

    float mountainMask = smoothstep(0.52, 0.82, continent);
    float mountains = ridgedFbm(warped * 1.15, 5, 2.0, 0.52);

    float height = 18.0;
    height += continent * 28.0;
    height += hills * 14.0;
    height += detail * 3.0;
    height += mountainMask * mountains * 55.0;

    return height;
}

void main() {
    ivec3 localPos = ivec3(gl_GlobalInvocationID.xyz);

    if (localPos.x >= CHUNK_SIZE || localPos.y >= CHUNK_SIZE || localPos.z >= CHUNK_SIZE) {
        return;
    }

    ivec3 worldPos = chunkPos * CHUNK_SIZE + localPos;

    float height = terrainHeight(vec2(worldPos.x,worldPos.z) * 0.02) * 0.0015 + 10 ;

    uint voxelType = 0u;

    if (float(worldPos.y) <= height) {
        float depthBelowSurface = height - float(worldPos.y);

        if (depthBelowSurface < 1.5) {
            voxelType = 1u; // Grass/topsoil
        } else if (depthBelowSurface < 5.0) {
            voxelType = 2u; // Dirt
        } else {
            voxelType = 3u; // Stone
        }
    }

    uint index = uint((localPos.x * CHUNK_AREA) + (localPos.y * CHUNK_SIZE) + localPos.z);
    voxels[index] = voxelType;
}